Add add-seccomp combinator

This combinator allows for the use of bubblewrap's `--add-seccomp-fd`
option. Since multiple invocations of this combinator are allowed, this
commit also introduces a new state attribute `seccompPermissions`.

The implementation uses `test -x` against the given argument to decide
whether to use input redirection to a FD or process substitution.
This commit is contained in:
Mathias Sven 2025-10-19 01:22:03 +01:00 • committed by Alex David
commit 23bf74dad6
3 changed files with 50 additions and 0 deletions

View file

@ -22,6 +22,7 @@ let
add-path = ./combinators/add-path.nix;
add-pkg-deps = ./combinators/add-pkg-deps.nix;
add-runtime = ./combinators/add-runtime.nix;
add-seccomp = ./combinators/add-seccomp.nix;
base = ./combinators/base.nix;
bind-nix-store-runtime-closure = ./combinators/bind-nix-store-runtime-closure.nix;
bind-pkg = ./combinators/bind-pkg.nix;

View file

@ -0,0 +1,48 @@
{
combinators,
helpers,
...
}:
let
inherit (combinators)
add-runtime
compose
defer
escape
include-once
;
in
{
sig = "String -> Permission";
doc = ''
Adds the cBPF program as a bubblewrap argument.
Accepts a path or a derivation that resolves to either a compiled cBPF program
or an executable that writes the program to stdout. In the latter case,
the executable will be run at each invocation of the wrapped binary at runtime.
This combinator can be composed according to the same rules as
bubblewrap's `--add-seccomp-fd` option.
See BWRAP(1) for more information.
'';
impl = path: compose [
(helpers.pushState "seccompPermissions" (escape path))
(include-once "seccomp" (
defer (
state:
add-runtime ''
declare -a SECCOMP_FILTERS=(${toString (state.seccompPermissions)})
for FILTER in "''${SECCOMP_FILTERS[@]}"; do
if [[ -x "$FILTER" ]]; then
exec {FILTER_FD}< <("$FILTER")
else
exec {FILTER_FD}<"$FILTER"
fi
RUNTIME_ARGS+=(--add-seccomp-fd "$FILTER_FD")
done
'' state
)
))
];
}

View file

@ -44,6 +44,7 @@ let
deferredPermissions = [ ]; # See defer combinator
additionalRuntimeClosures = [ ]; # See bind-nix-store-runtime-closure
dbusPermissions = [ ]; # See dbus combinator
seccompPermissions = [ ]; # See add-seccomp combinator
};
in
lib.pipe initialState (