88 lines
2.8 KiB
Nix
88 lines
2.8 KiB
Nix
{ pkgs, name, exe, applyCombinators }: let
|
|
inherit (pkgs) lib;
|
|
|
|
helpers = rec {
|
|
dataDir = "~/.local/share/jail.nix";
|
|
dataDirSubPath = subPath: "${dataDir}/${combinators.escape subPath}";
|
|
};
|
|
|
|
combinators = lib.mapAttrs
|
|
(_: v: v.impl combinators)
|
|
(import ./combinators.nix { inherit pkgs lib helpers; });
|
|
|
|
initial-state = {
|
|
name = name;
|
|
cmd = "${lib.getExe pkgs.bubblewrap}";
|
|
entry = if builtins.typeOf exe == "string" then lib.escapeShellArg exe else lib.getExe exe;
|
|
path = "${pkgs.coreutils}/bin";
|
|
argv = "\"$@\"";
|
|
runtime = "";
|
|
new-session = true;
|
|
hostname = "jail";
|
|
env = {};
|
|
namespaces = {};
|
|
included-once = []; # See include-once combinator
|
|
};
|
|
in lib.pipe initial-state (
|
|
# apply pre-user combinators
|
|
(with combinators; [
|
|
(unsafe-add-raw-args "--proc /proc")
|
|
(unsafe-add-raw-args "--dev /dev")
|
|
(unsafe-add-raw-args "--tmpfs /tmp")
|
|
(unsafe-add-raw-args "--tmpfs ~")
|
|
(unsafe-add-raw-args "--clearenv")
|
|
(unsafe-add-raw-args "--die-with-parent")
|
|
(readonly "/nix/store")
|
|
(readonly "/bin/sh")
|
|
(fwd-env "LANG")
|
|
(fwd-env "HOME")
|
|
(fwd-env "TERM")
|
|
|
|
(add-runtime ''
|
|
if [ ! -e ${helpers.dataDirSubPath "passwd"} ] || [ ! -e ${helpers.dataDirSubPath "group"} ]; then
|
|
mkdir -p ${helpers.dataDir}
|
|
echo "root:x:0:0:System administrator:/root:$(which nologin)" > ${helpers.dataDirSubPath "passwd"}
|
|
echo "$(id -un):x:$(id -u):$(id -g)::$HOME:$(which nologin)" >> ${helpers.dataDirSubPath "passwd"}
|
|
echo "root:x:0:" > ${helpers.dataDirSubPath "group"}
|
|
echo "$(id -gn):x:$(id -g):" >> ${helpers.dataDirSubPath "group"}
|
|
fi
|
|
'')
|
|
(ro-bind (noescape (helpers.dataDirSubPath "passwd")) "/etc/passwd")
|
|
(ro-bind (noescape (helpers.dataDirSubPath "group")) "/etc/group")
|
|
])
|
|
|
|
# apply user combinators
|
|
++ applyCombinators combinators
|
|
|
|
# apply post-user combinators
|
|
++ (with combinators; [
|
|
(s:
|
|
# See `--unshare-*` in BWRAP(1)
|
|
lib.pipe ["user" "ipc" "pid" "net" "uts" "cgroup"] [
|
|
(lib.filter (ns: !(s.namespaces.${ns} or false)))
|
|
(map (ns: "--unshare-${ns}"))
|
|
(builtins.concatStringsSep " ")
|
|
unsafe-add-raw-args
|
|
] s
|
|
)
|
|
(s: set-env "PATH" s.path s)
|
|
(s: if s.new-session then unsafe-add-raw-args "--new-session" s else s)
|
|
(s: lib.foldr (envVar:
|
|
assert pkgs.lib.isValidPosixName envVar;
|
|
unsafe-add-raw-args "--setenv ${envVar} ${s.env.${envVar}}"
|
|
) s (builtins.attrNames s.env))
|
|
])
|
|
|
|
# build jailed app from state
|
|
++ [
|
|
(state: ''
|
|
RUNTIME_ARGS=()
|
|
${state.runtime}
|
|
exec ${state.cmd} "''${RUNTIME_ARGS[@]}" -- ${state.entry} ${state.argv}
|
|
'')
|
|
(text: pkgs.writeShellApplication { inherit name text; })
|
|
|
|
# forward man pages
|
|
(jailed: if exe ? man then jailed // { inherit (exe) man; } else jailed)
|
|
]
|
|
)
|