jail.nix/lib/combinators/base.nix
Alex David b0a8a22983 Pull remaining default perms into base combinator
`base-permissions.nix` was the source of truth for all of the base
combinators, but it was not documented well anywhere.

To make this easier and more obvious for users, this commit pulls all
remaining custom permissions into a new `base` combinator which is
included by default. This way there is no more undocumented permissions
included by default, they are all documented in the `Default included
combinators` section of the docs.

This should also make it easier to override base permissions because
users can now just specify `base` instead of all of the
`unsafe-add-raw-args` calls unless they really want to change them.
2025-10-10 16:28:45 -07:00

50 lines
1.7 KiB
Nix

{ combinators, pkgs, ... }:
let
inherit (combinators)
add-pkg-deps
ro-bind
compose
fwd-env
unsafe-add-raw-args
;
in
{
sig = "Permission";
includedInBasePermissions = true;
doc = ''
This sets up a basic minimal set of permissions that a lot of software will
need.
This combinator:
* Sets up a fake proc at `/proc` (Using `--proc /proc` bwrap args)
* Sets up a fake dev at `/dev` (Using `--dev /dev` bwrap args)
* Sets up a tmpfs at `/tmp` (Using `--tmpfs /tmp` bwrap args)
* Sets up a tmpfs at your home (Using `--tmpfs ~` bwrap args)
* Ensures all processes in the jail are killed when the jail exits
(Using `--die-with-parent` bwrap arg)
* Adds coreutils to the package deps (`add-pkg-deps [ pkgs.coreutils ]`)
* Binds `/bin/sh` from `pkgs.bash`
(`ro-bind "''${pkgs.bash}/bin/sh" "/bin/sh"`)
* Clears the environment except `LANG`, `HOME` and `TERM`
This is included in the base permissions by default so you shouldn't need
to include it unless you override base permissions. It is exposed as a
combinator (like the other default included combinators) so that you can
use it in a custom
[`basePermissions`](advanced-configuration.md#basepermissions).
'';
impl = compose [
(unsafe-add-raw-args "--proc /proc")
(unsafe-add-raw-args "--dev /dev")
(unsafe-add-raw-args "--tmpfs /tmp")
(unsafe-add-raw-args "--tmpfs ~")
(unsafe-add-raw-args "--die-with-parent")
(add-pkg-deps [ pkgs.coreutils ])
(ro-bind "${pkgs.bash}/bin/sh" "/bin/sh")
(unsafe-add-raw-args "--clearenv")
(fwd-env "LANG")
(fwd-env "HOME")
(fwd-env "TERM")
];
}